From b570275c6c6b6da76ec6ba268a0c432262794cd9 Mon Sep 17 00:00:00 2001
From: Tim Pope <code@tpope.net>
Date: Wed, 10 Aug 2005 23:49:35 +0000
Subject: [PATCH] First attempt

---
 perl/sct6 | 621 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 621 insertions(+)
 create mode 100755 perl/sct6

diff --git a/perl/sct6 b/perl/sct6
new file mode 100755
index 0000000..fde8f7f
--- /dev/null
+++ b/perl/sct6
@@ -0,0 +1,621 @@
+#!/usr/bin/perl -w
+# $Id$
+# -*- perl -*- vim: ft=perl sw=4 sts=4
+
+# Brief usage instructions:
+# Create a ~/.sct6rc that has SID=yourssn and PIN=yourpin
+# You'll need to change the url below if you go anywhere but TAMUK.
+
+use strict;
+use LWP::UserAgent;
+use HTML::TableExtract;
+#use Time::Local;
+use Date::Calc::Object qw(Day_of_Week Decode_Day_of_Week Decode_Month Week_of_Year Monday_of_Week Day_of_Week_Abbreviation Delta_Days Add_Delta_Days Nth_Weekday_of_Month_Year Gmtime Mktime);
+use Date::Calendar::Profiles qw($Profiles);
+use Date::Calendar::Year;
+use vars qw($ua %opts %faculty);
+
+my ($response);
+
+$opts{'holidays'} = { # %{$Profiles->{'US-TX'}},
+    "Martin Luther King Day"    => "3/Mon/Jan",
+    "Good Friday"               => "-2",
+    "Spring Break Monday"	=> \&Spring_Break,
+    "Spring Break Tuesday"	=> \&Spring_Break,
+    "Spring Break Wednesday"	=> \&Spring_Break,
+    "Spring Break Thursday"	=> \&Spring_Break,
+    "Spring Break Friday"	=> \&Spring_Break,
+    "Spring Break Saturday"	=> \&Spring_Break,
+    "Study Day"                 => "4/Thu/Apr", # ?
+    "Memorial Day"              => "5/Mon/May",
+    "Independence Day"          => \&US_Independence,
+    "Labor Day"                 => \&US_Labor,
+    #"Columbus Day"              => "2/Mon/Oct",
+    "Thanksgiving Day"          => "4/Thu/Nov",
+    "Thanksgiving Friday"       => \&Thanksgiving_Friday,
+};
+
+sub Spring_Break {
+    my($year,$label) = @_;
+    $label =~ s/^Spring Break //;
+    return( Add_Delta_Days(
+	    Nth_Weekday_of_Month_Year($year,1,1,1),
+	    7*(11-1) # This is for the 11th Monday of the year
+	    +Decode_Day_of_Week($label)-1) );
+}
+
+sub Thanksgiving_Friday {
+    my($year,$label) = @_;
+    return( Add_Delta_Days(Nth_Weekday_of_Month_Year($year,11,4,4), 1) );
+}
+sub US_Independence # Fourth of July
+{
+    my($year,$label) = @_;
+    return( &Date::Calendar::Profiles::Nearest_Workday($year,7,4) );
+}
+sub US_Labor # First Monday after the first Sunday in September
+{
+    my($year,$label) = @_;
+    return( Add_Delta_Days(
+        Nth_Weekday_of_Month_Year($year,9,7,1), +1) );
+}
+
+my $config = $ENV{HOME} . "/.sct6rc";
+if (($ARGV[0] || "") eq '-F') {
+    shift;
+    $config = shift;
+}
+
+my $arg = "";
+$arg = shift if (defined($ARGV[0]) && $ARGV[0] =~ /^-\w$/);
+
+if (-r $config) {
+    open CONFIG, $config;
+    while(<CONFIG>) {
+	s/\#.*//;
+	next unless m/^([^=]*)=(.*)/;
+	$opts{$1}=$2;
+    }
+    close CONFIG;
+}
+my $domain = $opts{'domain'} || "as1.tamuk.edu:9003";
+my $url = "https://$domain/pls/PROD/";
+$url = $opts{'url'} if(defined($opts{'url'}));
+
+$ua = LWP::UserAgent->new;
+$ua->timeout(10);
+$ua->env_proxy;
+$ua->cookie_jar( {} );
+$ua->get("${url}twbkwbis.P_WWWLogin") or die "$!";
+$response = $ua->post("${url}twbkwbis.P_ValLogin", { sid => $opts{SID}, PIN => $opts{PIN} }) or die "$!";
+
+$response = $ua->get("${url}bwskflib.P_SelDefTerm"); # Valid terms
+die $response->status_line unless $response->is_success;
+my @terms = grep {s/^<option value="([^"]*)">.*/$1/i} (split( /\r?\n/, $response->content));
+die "Site down. Try again later.\n" unless (@terms);
+
+sub generate_id {
+    my ($section, $number) = split("-", shift);
+    my $id = 0;
+    foreach (split //, $section) {$id=26*$id+(ord($_)-1)%32;}
+    $id=10000*$id+$number;
+    return $id;
+}
+
+sub next_class {
+    my %class = @_;
+    $class{'duration'} =~ /(\d\d\d\d)(\d\d)(\d\d)-(\d\d\d\d)(\d\d)(\d\d)/;
+    my $days = Delta_Days($1,$2,$3,$4,$5,$6);
+    my $firstday = Date::Calc->new($1,$2,$3);
+    my $lastday = Date::Calc->new($4,$5,$6);
+    my $today = Date::Calc->new(Date::Calc->localtime(time+3600*6)->date);
+    my @days=();
+    foreach(split(" ",$class{'days'})) {
+	push @days, Decode_Day_of_Week($_);
+    }
+    my @off = (off_for_holidays(%class),off_for_exams(%class));
+    for($today = ($today > $firstday ? $today : $firstday); $today < $lastday; $today++) {
+	next unless(grep($_ == Day_of_Week($today->date), @days));
+	next if(grep($_ == $today, @off));
+	return $today;
+    }
+    $today = Date::Calc->new(Date::Calc->gmtime->date);
+    for($today = ($today < $lastday ? $today : $lastday); $today > $firstday; $today--) {
+	next unless(grep($_ == Day_of_Week($today->date), @days));
+	next if(grep($_ == $today, @off));
+	return $today;
+    }
+    return undef;
+}
+
+sub off_for_holidays {
+    my %class = @_;
+    $class{'duration'} =~ /(\d\d\d\d)(\d\d)(\d\d)-(\d\d\d\d)(\d\d)(\d\d)/;
+    my $days = Delta_Days($1,$2,$3,$4,$5,$6);
+    my $firstday = Date::Calc->new($1,$2,$3);
+    my $lastday = Date::Calc->new($4,$5,$6);
+    my $year = Date::Calendar::Year->new($1, $opts{'holidays'});
+    my @holidays=();
+    my @days=();
+    foreach(split(" ",$class{days})) {
+	$days[Decode_Day_of_Week($_)] = 1;
+    }
+    foreach ($year->search("")) {
+	my $good=1;
+	#foreach my $x ($year->labels($_)) {
+	#    $good=0 if ($x =~ /Veteran/ or $x =~ /President/);
+	#}
+	next unless ($year->is_full($_) && $_>=$firstday && $_<=$lastday);
+	push @holidays, $_
+	    if (defined($days[Day_of_Week($_->date)]) && $good > 0);
+    }
+    return wantarray ? @holidays : "@holidays";
+}
+
+sub off_for_exams {
+    my %class = @_;
+    my $time = $class{'begin'} . "-" . $class{'end'};
+    $class{'duration'} =~ /\d{8}-(\d\d\d\d)(\d\d)(\d\d)/;
+    my $lastday = Date::Calc->new($1,$2,$3);
+    return wantarray ? () : undef unless (Day_of_Week($lastday->date) == 7);
+    my $beginning="(08:00-09:15|11:00-12:15|14:00-15:15|17:00-18:15|17:30-18:45|20:00-21:15|20:30-21:45)";
+    my $ending   ="(06:30-07:45|09:30-10:45|12:30-13:45|15:30-16:45|18:30-19:45|19:00-20:15)";
+    my $days = join(" ",map {Decode_Day_of_Week($_)} split(/ /, $class{'days'}));
+    if($days eq "1 3") {
+	if($time =~ /$beginning/) {
+	    return $lastday-4;
+	} elsif($time =~ /$ending/) {
+	    return $lastday-6;
+	}
+    } elsif($days eq "2 4") {
+	if($time =~ /$beginning/) {
+	    return $lastday-3;
+	} elsif($time =~ /$ending/) {
+	    return $lastday-5;
+	}
+    } elsif($days eq "5") {
+	return $lastday-2;
+    }
+    return wantarray ? () : "";
+}
+
+sub capitalize {
+    local $_ = shift || "";
+    s/ +$//;
+    s/\b([A-Z])([A-Z]*)\b/$1\L$2/g;
+    s/\b(I)(i*)\b/$1\U$2/g;
+    s/\bUs\b/US/g;
+    s/ (And|For|Of|Or|The|To|With) / \l$1 /g;
+    s/\b(Mc)([a-z])/$1\u$2/g;
+    s/\bTba\b/TBA/g;
+    s/\b(Tcp\/Ip|Pc)\b/\U$&/g;
+    s/\bThru\b/Through/g;
+    s/\bAcct\b/Accounting/g;
+    s/\bAmer\b/American/g;
+    s/\bChem\b/Chemistry/g;
+    s/\bComp\b/Composition/g;
+    s/\bFed\b/Federal/g;
+    s/\bGen\b/General/g;
+    s/\bIntro\b/Introduction/g;
+    s/\bPrgm\b/Programming/g;
+    s/\bOp Sys\b/Operating System/g;
+    #s/\bGovt\b/Government/g;
+    s/\bLit\b/Literature/g;
+    s/\bPrin\b/Principles/g;
+    s/\bBus\b/Business/g;
+    return $_;
+}
+
+sub get_schedule_terms {
+    my (@sterms, @a);
+    @a=('10','20','30','40'); # XXX 10 is fall, others are speculation
+    my @localtime=localtime();
+    if ($localtime[4]<3) { # Through Mar 31
+	@sterms=((1900+$localtime[5]).$a[1]);
+    } elsif ($localtime[4]<5) { # Through May 31
+	@sterms=((1900+$localtime[5]).$a[1],(1900+$localtime[5]).$a[2]);
+    } elsif ($localtime[4]<7) { # through July 31
+	@sterms=((1900+$localtime[5]).$a[2],(1900+$localtime[5]).$a[3]);
+    } elsif ($localtime[4]<8) { # through Aug 31
+	@sterms=((1900+$localtime[5]).$a[3],(1901+$localtime[5]).$a[0]);
+    } elsif ($localtime[4]<10) { # through Oct 31
+	@sterms=((1901+$localtime[5]).$a[0]);
+    } else {
+	@sterms=((1901+$localtime[5]).$a[0],(1901+$localtime[5]).$a[1]);
+    }
+    return @sterms;
+}
+
+sub get_schedule {
+    my @readheaders = ("Type", "Time", "Days", "Where", "Date Range", "Schedule Type", "Instructors");
+    my @class;
+    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
+    #@readheaders = ("Course", "Days\xa0TimeLocation", "Session and Dates", "Instructor", "Credit", "CallNumber", "GradeType", "Message");
+    my $tf = new HTML::TableExtract( headers => [ @readheaders ] );
+    my (@schedule, @terms, $classid, $title, $begin, $end, $times, $days, $session);
+    @terms = get_schedule_terms();
+    foreach (@_ ? @_ : @terms) {
+	$response = $ua->get("${url}bwskfshd.P_CrseSchdDetl?term_in=$_" );
+	die $response->status_line unless $response->is_success;
+	$te->parse($response->content);
+	foreach my $l (split (/\n/, $response->content)) {
+	    next unless $l =~ s/.*<CAPTION class=[^>]*>(.* - .... \d\d\d\d \d\d\d)<\/caption>.*/$1/i;
+	    push @class, $l;
+	}
+	#$tf->parse($response->content);
+	#print $response->content;
+    }
+    foreach my $ts ($te->table_states) {
+	foreach my $row ($ts->rows) {
+	    #map { s/\xa0//g; $_} @$row;
+	    #$row->[0] =~ s/.*launchWebCT\("([^"]*)"\).*/$1/s;
+	    #$row->[0] =~ s/(.*) ?<[Bb][Rr][^>]*>(.*)/capitalize($2)/eg;
+	    $classid = (shift @class);
+	    $title = $classid;
+	    $classid =~ s/.* - //;
+	    $classid =~ s/ /-/g;
+	    $title =~ s/ - .*//;
+	    $row->[6] = capitalize($row->[6]);
+	    $row->[6] =~ s/([A-Z]r?)$/$1./;
+	    $row->[6] =~ s/ *\([A-Z]\)//;
+	    $row->[1] =~ s/ ?([ap])m/\u$1M/g;
+	    $row->[1] =~ s/ - /-/;
+	    ($begin, $end) = split(/ ?- ?/, $row->[1]);
+	    $begin =~ s/^(\d):/0$1:/;
+	    $end =~ s/^(\d):/0$1:/;
+	    if ($begin =~ /pm$/i && $begin !~ /^12/) {
+		$begin =~ s/^(\d?\d)/$1+12/e;
+	    }
+	    if ($end =~ /pm$/i && $end !~ /^12/) {
+		$end =~ s/^(\d?\d)/$1+12/e;
+	    }
+	    $begin =~ s/ ?[AP]M//;
+	    $end =~ s/ ?[AP]M//;
+	    $row->[4] =~ s/([A-Za-z]{3,9})/(Decode_Month($1)<10?"0":"").Decode_Month($1)/eg;
+	    $row->[4] =~ s/(\d\d?) (\d\d), (\d\d\d\d)/$3$1$2/g;
+	    $row->[4] =~ s/ - /\n/;
+	    $row->[3] =~ s/(ON|MAIN) CAMPUS\n|Palo Alto Building \d* //ig;
+	    $row->[3] =~ s/\n/ /g;
+	    push @schedule, {
+		id => $classid,
+		title => $title,
+		#session => $row->[1],
+		instructor => $row->[6],
+		#credits => $row->[3],
+		#callnumber => $row->[4],
+		#gradetype => $row->[5],
+		days => $row->[2],
+		'time' => $row->[1],
+		begin => $begin,
+		end => $end || undef,
+		duration => $row->[4],
+		location => $row->[3],
+		#message => $row->[10],
+	    };
+	    #print join (" ", values %{$schedule[$#schedule]}), "\n";
+	}
+    }
+    return @schedule;
+}
+
+sub get_faculty_email {
+    my ($name, $school, $email);
+    if((-f $ENV{'HOME'} . "/public_html/faculty.csv") && ! %faculty) {
+	open INS, $ENV{'HOME'} . "/public_html/faculty.csv";
+	while($_ = <INS>) {
+	    chomp;
+	    m/"([^"]*)",([^,]*),([^,]*)/;
+	    ($name, $email, $school) = ($1, $2, $3);
+	    $name =~ s/^([^,]*), ([^,]*)(.*)$/$2 $1$3/;
+	    $name =~ s/ [A-Z]\.//g;
+	    $name = lc $name;
+	    $name =~ s/\W//g;
+	    $faculty{$name} = $email;
+	}
+    }
+    $name = shift;
+    $name =~ s/ [A-Z]r?\.//g;
+    $name = lc $name;
+    $name =~ s/\W//g;
+    return $faculty{$name};
+}
+
+sub get_mhc_header {
+return (
+"X-SC-Subject: New Years Day\nX-SC-Category: Holiday\nX-SC-Cond: 1 Jan\nX-SC-Duration: 00010101-\nX-SC-Record-Id: <New_Years_Day\@from.sctweb>\n",
+"X-SC-Subject: Martin Luther King, Jr. Day\nX-SC-Category: Holiday\nX-SC-Cond: 3rd Mon Jan\nX-SC-Duration: 19870119-\nX-SC-Record-Id: <Martin_Luther_King_Jr_Day\@from.sctweb>\n",
+"X-SC-Subject: Presidents Day\nX-SC-Category: Holiday\nX-SC-Cond: 3rd Mon Feb\nX-SC-Duration: 19710515-\nX-SC-Record-Id: <Presidents_Day\@from.sctweb>\n",
+"X-SC-Subject: Memorial Day\nX-SC-Category: Holiday\nX-SC-Cond: Last Mon May\nX-SC-Duration: 19710531-\nX-SC-Record-Id: <Memorial_Day\@from.sctweb>\n",
+"X-SC-Subject: Independence Day\nX-SC-Category: Holiday\nX-SC-Cond: 4 Jul\nX-SC-Duration: 17760704-\nX-SC-Record-Id: <Independence_Day\@from.sctweb>\n",
+"X-SC-Subject: Labor Day\nX-SC-Category: Holiday\nX-SC-Cond: 1st Mon Sep\nX-SC-Duration: 18840901-\nX-SC-Record-Id: <Labor_Day\@from.sctweb>\n",
+"X-SC-Subject: Columbus Day\nX-SC-Category: Holiday\nX-SC-Cond: 2nd Mon Oct\nX-SC-Duration: 19711011-\nX-SC-Record-Id: <Columbus_Day\@from.sctweb>\n",
+"X-SC-Subject: Veterans Day\nX-SC-Category: Holiday\nX-SC-Cond: 11 Nov\nX-SC-Duration: 19261111-\nX-SC-Record-Id: <Veterans_Day\@from.sctweb>\n",
+"X-SC-Subject: Thanksgiving\nX-SC-Category: Holiday\nX-SC-Cond: 4th Thu Nov\nX-SC-Duration: 14921122-\nX-SC-Record-Id: <Thanksgiving\@from.sctweb>\n",
+"X-SC-Subject: Christmas\nX-SC-Category: Holiday\nX-SC-Cond: 25 Dec\nX-SC-Duration: 00011225-\nX-SC-Record-Id: <Christmas\@from.sctweb>\n",
+);
+}
+
+sub do_mhc_schedule {
+    $| = 1;
+    my %days = (M => "Mon", T => "Tue", W => "Wed", R => "Thu", F => "Fri", S => "Sat", U => "SU");
+    my @mon = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
+    my ($file, $current, @mhc, @schedule);
+    $file = shift unless (!defined $_[0] or $_[0] =~ /^\d/);
+    @schedule = get_schedule(@_);
+    @mhc = get_mhc_header;
+    if(defined($file) && (-d $file)) {
+	my @mhc2;
+	foreach (@mhc) {
+	    $_ =~ s/X-SC-Subject: ([^\n]*)/X-SC-Subject: $1\nSubject: $1/;
+	    $_ =~ s/X-SC-Category: ([^\n]*)/X-SC-Category: $1\nFrom: $1/;
+	    $_ =~ s/X-SC-Duration: (\d\d\d\d)(\d\d)(\d\d)-/"X-SC-Duration: $1$2$3-\nDate: $3 " . $mon[$2-1] . " 1970 12:00:00 +0000"/e;
+	    push @mhc2, $_;
+	}
+	@mhc = @mhc2;
+    }
+    foreach my $row (@schedule) {
+	map {s/\n/-/g if defined; $_} %$row;
+	my $id=generate_id($row->{'id'});
+	$row->{'days'} =~ s/([MTWRFS])/ $days{$1}/g;
+	$row->{'days'} =~ s/^ //;
+	#$row->{'duration'} =~ s/(\d\d)-(\d\d)-(\d\d)/20$3$1$2/g;
+	my @day = map { "!" . $_ } (off_for_holidays(%$row),off_for_exams(%$row));
+	$current = "";
+	#print "# $id\n";
+	$current .= "X-SC-Subject: " . $row->{'title'} . "\n";
+	$current .= "X-SC-Location: " . $row->{'location'} . "\n";
+	$current .= "X-SC-Category: School\n";
+	$current .= "X-SC-Cond: " . $row->{'days'} . "\n";
+	$current .= "X-SC-Time: ".$row->{'begin'}."-".$row->{'end'}."\n";
+	$current .= "X-SC-Duration: " . $row->{'duration'} . "\n";
+	$current .= "X-SC-Day: @day\n" if(exists $day[0]);
+	$current .= "X-SC-Alarm: 15 minutes\n";
+	$current .= "X-SC-Record-Id: <".$row->{'id'}."\@from.sctweb>\n";
+	if(defined($file) && (-d $file)) {
+	    $row->{'instructor'} =~ s/^([^,]*), ([^,]*)(.*)/$2 $1$3/;
+	    my $email = get_faculty_email $row->{'instructor'};
+	    $row->{'instructor'} = '"' . $row->{'instructor'} . '" <'. ($email || ($1 || "unknown") . "\@from.sctweb") . ">";
+	    $row->{'duration'} =~ /^(\d\d\d\d)(\d\d)(\d\d)-\d{8}$/;
+	    $row->{'begin'} =~ /^(\d\d):(\d\d)$/;
+	    my $next = next_class(%$row);
+	    my @date = Gmtime(Mktime($next->date,$1,$2,0));
+	    $current .= sprintf "Date: %s, %2d %s %4d %02d:%02d:00 +0000\n", Day_of_Week_Abbreviation($date[7]), $date[2], $mon[$date[1]-1], $date[0], $date[3], $date[4], $date[5];
+	    $current .= "Subject: " . $row->{'title'} . "\n";
+	    $current .= "From: " . $row->{'instructor'} . "\n";
+	}
+	#print "\n$current";
+	push @mhc, $current;
+    }
+    if(defined($file) && (-d $file)) {
+	my @lines;
+	foreach my $name (<$file/[1-9]*>) {
+	    next unless $name =~ /^$file\/[1-9][0-9]*$/;
+	    open FH, $name;
+	    @lines = <FH>;
+	    close FH;
+	    foreach (@lines) {
+		unlink $name if /^X-SC-Record-Id: <.*\@from.sctweb>/;
+	    }
+	}
+	my $i=0;
+	foreach (@mhc) {
+	    while(-f ++$i) {}
+	    open FH, ">$file/$i" or die $!;
+	    print FH $_;
+	    close FH;
+	}
+    } else {
+	open(STDOUT, ">" . $file) if(defined($file));
+	print "# MHC school schedule\n# Autogenerated by sctweb ".localtime()."\n\n";
+	print join("\n", @mhc);
+    }
+}
+
+sub do_csv_schedule {
+    $| = 1;
+    my %days = (M => "Mon", T => "Tue", W => "Wed", R => "Thu", F => "Fri", S => "Sat", U => "SU");
+    my @mon = qw(Jan. Feb. Mar. Apr. May June July Aug. Sept. Oct. Nov. Dec.);
+    my (@terms, $file, $current, @mhc, @schedule);
+    $file = shift unless (!defined $_[0] or $_[0] =~ /^\d/);
+    @schedule = get_schedule(@_);
+    open(STDOUT, ">" . $file) if(defined($file));
+    foreach my $row (@schedule) {
+	map {s/\n/-/g if defined; $_} %$row;
+	my $id=generate_id($row->{'id'});
+	$row->{'days'} =~ s/([MTWRFS])/ $days{$1}/g;
+	$row->{'days'} =~ s/^ //;
+	$row->{'instructor'} =~ s/^([^,]*), ([^,]*)/$2 $1/;
+	my $next = next_class(%$row);
+	$current = "";
+	#print "# $id\n";
+	$current .= $row->{'id'} . ",";
+	$current .= $row->{'title'} . ",";
+	$current .= '"' . $row->{'instructor'} . '",';
+	$next =~ /^(\d\d\d\d)(\d\d)(\d\d)$/;
+	$current .= $1 . "-". $2 ."-" . $3 . "\n";
+	print $current;
+    }
+}
+
+sub do_vcalendar_schedule {
+    $| = 1;
+    my %days = (M => "MO", T => "TU", W => "WE", R => "TH", F => "FR", S => "SA", U => "SU");
+    my $file = shift if (defined $_[0] and $_[0] !~ /^\d/);
+    my @schedule = get_schedule(@_);
+    open(STDOUT, ">>" . $file) if(defined($file) && (! -d $file));
+    open(STDOUT, ">/dev/null") if(defined($file) && (-d $file));
+    print "BEGIN:VCALENDAR\r\nVERSION:1.0\r\n";
+    foreach my $row (@schedule) {
+	map { s/\n/-/g; $_} %$row;
+	$row->{'instructor'} =~ s/^([^,]*), ([^,]*)/$2 $1/;
+	$row->{'days'} =~ s/([MTWRFS])/ $days{$1}/g;
+	$row->{'days'} =~ s/^ //;
+	#$row->{'duration'} =~ s/(\d\d)-(\d\d)-(\d\d)/20$3$1$2/g;
+	my @day = (off_for_holidays(%$row),off_for_exams(%$row));
+	my $day = "";
+	if(exists($day[0])) {
+	    $day = join(";", @day);
+	    $day =~ s/\b(\d{8})\b/$1T000000/g;
+	}
+	my ($starttime, $stoptime)=($row->{'begin'}, $row->{'end'});
+	my ($startdate, $stopdate)=split(/-/, $row->{'duration'});
+	$starttime =~ s/://;
+	$stoptime =~ s/://;
+	if(defined($file) && (-d $file)) {
+	    open FH, ">$file/" . $row->{'id'} . ".vcs" or die "$!";
+	    select FH;
+	    print "BEGIN:VCALENDAR\r\nVERSION:1.0\r\n";
+	}
+	print "BEGIN:VEVENT\r\n";
+	print "SUMMARY:", $row->{'title'}, "\r\n";
+	print "DESCRIPTION:", $row->{'id'}, "\r\n";
+	print "LOCATION:", $row->{'location'}, "\r\n";
+	print "CATEGORIES:Education\r\n";
+	print "DTSTART:", $startdate."T".$starttime, "00\r\n";
+	print "DTEND:", $startdate."T".$stoptime, "00\r\n";
+	print "RRULE:W1 ", $row->{'days'} . " $stopdate", "T000000\r\n";
+	print("EXDATE:$day\r\n") if($day);
+	print "ATTENDEE;ROLE=OWNER;STATUS=CONFIRMED:", $opts{'name'}, "\r\n" if(defined($opts{'name'}));
+	print "ATTENDEE;ROLE=ORGANIZER;STATUS=CONFIRMED:", $row->{'instructor'}, " <" . (get_faculty_email($row->{'instructor'}) || "fake\@ddress"), ">\r\n";
+	print "END:VEVENT\r\n";
+	if(defined($file) && (-d $file)) {
+	    print "END:VCALENDAR\r\n";
+	    close FH;
+	    select STDOUT;
+	}
+    }
+    print "END:VCALENDAR\r\n";
+}
+
+sub do_html_schedule {
+    my @showheaders = ("Section ID/Title", "Instructor", "Days", "Time", "Duration", "Location");
+    my $shade = "dark";
+    my @schedule = get_schedule(@_);
+    print '<table id="schedule" cellpadding="3" cellspacing="0">'."\n<tr><th>";
+    print join("</th><th>",@showheaders);
+    print "</th></tr>\n";
+	foreach my $row (@schedule) {
+	    map { s/\n/<br \/>/g; $_} %$row;
+	    $row->{'time'} =~ s/-/-<wbr \/>/;
+	    $row->{'duration'} =~ s/\d\d(\d\d)(\d\d)(\d\d)/$2-$3-$1/g;
+	    print '<tr class="'.$shade.'">';
+	    $shade = ($shade eq "dark"?"light":"dark");
+	    print '<td class="idtitle">';
+	    print '<span class="sectionid">' .$row->{'id'}. '</span><br />';
+	    print '<span class="coursetitle">' .$row->{'title'}. '</span></td>';
+	    my $instructor = $row->{'instructor'};
+	    $instructor =~ s/^([^,]*), ([^,]*)(.*)/$2 $1$3/;
+	    my $email = get_faculty_email($instructor);
+	    #if($email) {
+		#print '<td><a href="mailto:' . $email . '">'
+		#. $row->{'instructor'} . "</a></td>";
+	    # } else {
+		print "<td>" . $row->{'instructor'} . "</td>";
+	    #}
+	    print "<td>" . $row->{'days'} . "</td>";
+	    print "<td>" . $row->{'time'} . "</td>";
+	    print "<td>" . $row->{'duration'} . "</td>";
+	    print "<td>" . $row->{'location'} . "</td>";
+	    print "</tr>\n";
+	}
+    print "</table>\n";
+}
+
+sub do_html_grades {
+    my @readheaders = ("Section ID", "Course Title", "Grade", "Earned  Hours", "Quality  Hours", "Quality  Points", "GPA");
+    @readheaders = ("Section", "Course Title", "FinalGrade", "Earned Hours", "Quality Hours", "Quality Points", "GPA") if($opts{'school'} eq 'tamuk');
+    my @showheaders = ("Section ID", "Course Title", "Grade", "Earned<br />Hours", "Quality<br />Hours", "Quality<br />Points");
+    my ($row, $lastrow);
+    my $shade = "dark";
+    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
+    my $response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN|Term&tserve_trans_config=rgrdterm.cfg"); # Valid grading terms
+    die $response->status_line unless $response->is_success;
+    #my @terms = reverse grep {s/^<option value="([^"]*)">.*/$1/} (split( /\r\n/, $response->content));
+    my @terms = ();
+    my $year = Date::Calc->localtime->year;
+    for(my $y=$year-4;$y<=$year;$y++) { push @terms, ($y.2,$y."F",$y.3,$y.4,$y.1,$y."S"); }
+    foreach(@_ ? @_ : @terms) {
+	$response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN|Term&tserve_trans_config=rgrades.cfg&Term=".($_) );
+	die $response->status_line unless $response->is_success;
+	$te->parse($response->content);
+    }
+    print '<table id="grades" cellpadding="3" cellspacing="0">'."\n<tr>";
+    print '<th align="left" class="sectionid">', $showheaders[0];
+    print '</th><th align="left" class="coursetitle">', $showheaders[1];
+    print '</th><th align="center" class="grade">';
+    print join('</th><th align="center" class="right-number">',@showheaders[2 .. 5]);
+    print "</th></tr>\n";
+    foreach my $ts ($te->table_states) {
+	foreach my $row ($ts->rows) {
+	    map { s/^\s+//; s/\xa0|\r//g; s/\n/<br \/>/g; $_} @$row;
+	    $row->[1] = capitalize($row->[1]);
+	    $row->[1] =~ s/&/&amp;/g;
+	    $row->[0] =~ s/Cumulative through/Cumulative: through/;
+	    $row->[0] =~ s/Cumulative:(.*) (\d{4}) (.*)/Cumulative:$1 $3 $2/;
+	    $lastrow=$row;
+	    next if $row->[0] =~ /:|Current Term/;
+	    print '<tr class="'.$shade.'">';
+	    $shade = ($shade eq "dark"?"light":"dark");
+	    print '<td align="left" class="sectionid">', $$row[0], '</td>';
+	    print '<td align="left" class="coursetitle">', $$row[1], '</td>';
+	    print '<td align="center" class="grade">';
+	    #print join('</td><td>', @$row[0 .. 1]);
+	    print join('</td><td align="right" class="right-number">', @$row[2 .. 5]);
+	    print "</td></tr>\n";
+	}
+    }
+    print '<tr class="cumulative '.$shade.'"><td id="cumulative" colspan="2">', capitalize($lastrow->[0]);
+    #shift @$lastrow; shift @$lastrow;
+    print '</td><td align="center" id="gpa" class="grade">';
+    print $$lastrow[6];
+    print '</td><td align="right" class="right-number">';
+    print join('</td><td align="right" class="right-number">', @$lastrow[3 .. 5]);
+    print "</td></tr>\n";
+    print "</table>\n";
+}
+
+sub do_faculty {
+    my @readheaders = ("Name", "College", "Email");
+    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
+    foreach(qw(a b c d e f g h i j k l m n o p q r s t u v w x y z)) {
+	my $response = $ua->get("http://$domain/fs/".$_."dir.htm");
+	die $response->status_line unless $response->is_success;
+	$te->parse($response->content);
+    }
+    foreach my $ts ($te->table_states) {
+	foreach my $row ($ts->rows) {
+	    map { s/[\r\n]//g; $_} @$row;
+	    $row->[0] = capitalize($row->[0]);
+	    $row->[0] =~ s/([A-Z]r?)$/$1./;
+	    print '"'.$row->[0].'",',$row->[2].',', $row->[1], "\n";
+	}
+    }
+}
+
+sub do_transcripts {
+    $response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN&tserve_trans_config=rtranscr.cfg&CareerReqNum=1");
+    foreach (split /\n/, $response->content) {
+	next unless s/^\&nbsp;|<pre>// || s/\&nbsp;/ /;
+	s/<\/?([Hh]\d|[Bb])>//g;
+	next if /<\/td>/;
+	print "$_\n";
+    }
+}
+
+if ($arg eq "-g") {
+    do_html_grades(@ARGV);
+} elsif ($arg eq "-s") {
+    do_html_schedule(@ARGV);
+} elsif ($arg eq "-m") {
+    do_mhc_schedule(@ARGV);
+} elsif ($arg eq "-c") {
+    do_csv_schedule(@ARGV);
+} elsif ($arg eq "-v") {
+    do_vcalendar_schedule(@ARGV);
+} elsif ($arg eq "-t") {
+    do_transcripts;
+} elsif ($arg eq "-f") {
+    do_faculty;
+}
+
+$ua->get("${url}twbkwbis.P_Logout"); # Logout
-- 
2.30.2