#!/usr/bin/perl -w
# $Id$
# -*- perl -*- vim: ft=perl sw=4 sts=4

# Brief usage instructions:
# Create a ~/.sctwebrc that has SID=yourssn and PIN=yourpin
# You'll need to change the url below if you go anywhere but Northwest Vista.

use strict;
use LWP::UserAgent;
use HTML::TableExtract;
use Time::Local;
use vars qw($ua %opts);
my ($ts, $row, $response);
my $url="https://sctweb.accd.edu/ia-bin4/tsrvweb.exe?WID=W&tserve_tip_read_destroy&tserve_host_code=4&tserve_tiphost_code=0";

if (-r $ENV{HOME} . "/.sctwebrc") {
    open CONFIG, $ENV{HOME} . "/.sctwebrc";
    while(<CONFIG>) {
	s/\#.*//;
	next unless m/^([^=]*)=(.*)/;
	$opts{$1}=$2;
    }
    close CONFIG;
}

$ua = LWP::UserAgent->new;
$ua->timeout(10);
$ua->env_proxy;
$ua->cookie_jar( {} );
$ua->get("$url&tserve_tip_write=||WID&tserve_transconfig=astulog.cfg") or die "$!";
$response = $ua->post("$url&tserve_trans_config=astulog.cfg", { tserve_tip_write => "%7C%7CWID%7CSID%7CPIN", SID => $opts{SID}, PIN => $opts{PIN} }) or die "$!";

$response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN|Term&tserve_trans_config=" . ("regterm.cfg"||"rgrdterm.cfg")); # Valid terms
die $response->status_line unless $response->is_success;
my @terms = grep {s/^<option value="([^"]*)">.*/$1/} (split( /\r\n/, $response->content));
die "Site down. Try again later.\n" unless (@terms);

sub generate_id {
    my ($section, $number) = split("-", shift);
    my $id = 0;
    foreach (split //, $section) {$id=26*$id+(ord($_)-1)%32;}
    $id=10000*$id+$number;
    return $id;
}

sub off_for_exams {
    $_[3] =~ /\d{8}-(\d\d\d\d)(\d\d)(\d\d)/;
    my @finalday = localtime timelocal(0,0,0,$3,$2-1,$1);
    return undef unless ($finalday[6] == 0);
    my $beginning="(08:00-09:15|11:00-12:15|14:00-15:15|17:00-18:15|17:30-18:45|20:00-21:15|20:30-21:45)";
    my $ending   ="(06:30-07:45|09:30-10:45|12:30-13:45|15:30-16:45|18:30-19:45|19:00-20:15)";
    if($_[1] eq "Mon Wed") {
	if($_[2] =~ /$beginning/) {
	    $_[3] =~ /\d{8}-(\d{8})/;
	    return "!" . ($1-4);
	} elsif($_[2] =~ /$ending/) {
	    $_[3] =~ /\d{8}-(\d{8})/;
	    return "!" . ($1-6);
	}
    } elsif($_[1] eq "Tue Thu") {
	if($_[2] =~ /$beginning/) {
	    $_[3] =~ /\d{8}-(\d{8})/;
	    return "!" . ($1-3);
	} elsif($_[2] =~ /$ending/) {
	    $_[3] =~ /\d{8}-(\d{8})/;
	    return "!" . ($1-5);
	}
    } else {
	return "";
    }
}

sub capitalize {
    local $_ = shift;
    s/\b([A-Z])([A-Z]*)\b/$1\L$2/g;
    s/\b(I)(i*)\b/$1\U$2/g;
    s/\bUs\b/US/g;
    s/ (And|For|Of|Or|The|To|With) / \l$1 /g;
    s/\b(Ma?c)([a-z])/$1\u$2/g;
    s/\b(Tcp\/Ip|Pc)\b/\U$&/g;
    s/\bThru\b/Through/g;
    s/\bAcct\b/Accounting/g;
    s/\bAmer\b/American/g;
    s/\bChem\b/Chemistry/g;
    s/\bComp\b/Composition/g;
    s/\bFed\b/Federal/g;
    s/\bGen\b/General/g;
    #s/\bGovt\b/Government/g;
    s/\bLit\b/Literature/g;
    s/\bPrin\b/Principles/g;
    return $_;
}

sub get_schedule_terms {
    my @terms;
    my @localtime=localtime();
    if ($localtime[4]<3) { # Through Mar 31
	@terms=((1900+$localtime[5])*10+2);
    } elsif ($localtime[4]<5) { # Through May 31
	@terms=((1900+$localtime[5])*10+2,(1900+$localtime[5])*10+3);
    } elsif ($localtime[4]<7) { # through July 31
	@terms=((1900+$localtime[5])*10+3,(1900+$localtime[5])*10+4);
    } elsif ($localtime[4]<8) { # through Aug 31
	@terms=((1900+$localtime[5])*10+4,(1900+$localtime[5])*10+1);
    } elsif ($localtime[4]<10) { # through Oct 31
	@terms=((1900+$localtime[5])*10+1);
    } else {
	@terms=((1900+$localtime[5])*10+1,(1901+$localtime[5])*10+2);
    }
    return @terms;
}

sub do_mhc_schedule {
    my @readheaders = ("Section ID/Title", "Days", "Time", "Start/EndDates", "Site/Building/Room");
    my %days = (M => "Mon", T => "Tue", W => "Wed", R => "Thu", F => "Fri", S => "Sat");
    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
    my (@terms, $row);
    @terms = get_schedule_terms();
    foreach(@ARGV || @terms) {
	$response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN|Term&tserve_trans_config=" . ($opts{cfg} || "rstusch" || "rgrades") . ".cfg&Term=".($_) );
	die $response->status_line unless $response->is_success;
	$te->parse($response->content);
    }
    print "# MHC school schedule\n";
    print "# Autogenerated by sctweb ".localtime()."\n";
    foreach $ts ($te->table_states) {
	foreach $row ($ts->rows) {
	    map { s/\xa0//g; s/\n/-/g; $_} @$row;
	    $row->[0] =~ s/.*launchWebCT\("([^"]*)"\).*/$1/s;
	    $row->[0] =~ s/(.*) <BR>//g;
	    my $id=generate_id($1);
	    $row->[0] = capitalize($row->[0]);
	    $row->[1] =~ s/([MTWRFS])/ $days{$1}/g;
	    $row->[1] =~ s/^ //;
	    if($row->[2] =~ /^(\d\d):\d\d-(\d\d):\d\dPM$/) {
		$row->[2] =~ s/^(\d\d)/$1+12/e
		if($1 < $2);
		$row->[2] =~ s/-(\d\d)/"-".($1+12)/e;
		$row->[2] =~ s/PM$//;
	    } else { $row->[2] =~ s/AM$//; }
	    $row->[3] =~ s/(\d\d)-(\d\d)-(\d\d)/20$3$1$2/g;
	    $row->[4] =~ s/ON CAMPUS-//g;
	    $row->[4] =~ s/-/ /g;
	    my $day = off_for_exams(@$row);
	    print "\n";
	    print "# $id\n";
	    print "X-SC-Subject: ", $row->[0], "\n";
	    print "X-SC-Category: School\n";
	    print "X-SC-Cond: ", $row->[1], "\n";
	    print "X-SC-Time: ", $row->[2], "\n";
	    print "X-SC-Duration: ", $row->[3], "\n";
	    print("X-SC-Day: ", $day, "\n") if(defined($day));
	    print "X-SC-Location: ", $row->[4], "\n";
	}
    }
}

sub do_html_schedule {
    my @readheaders = ("Section ID/Title", "Instructor", "Days", "Time", "Start/EndDates", "Site/Building/Room");
    my @showheaders = ("Section ID/Title", "Instructor", "Days", "Time", "Duration", "Location");
    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
    my (@terms, $row);
    @terms = get_schedule_terms();
    foreach(@ARGV || @terms) {
	$response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN|Term&tserve_trans_config=" . ($opts{cfg} || "rstusch" || "rgrades") . ".cfg&Term=".($_) );
	die $response->status_line unless $response->is_success;
	$te->parse($response->content);
    }
    print '<table cellpadding="3" cellspacing="0">'."\n<tr><th>";
    print join("</th><th>",@showheaders);
    print "</th></tr>\n";
    foreach $ts ($te->table_states) {
	foreach $row ($ts->rows) {
	    map { s/\xa0//g; s/\n/<br \/>/g; $_} @$row;
	    $row->[0] =~ s/.*launchWebCT\("([^"]*)"\).*/$1/s;
	    $row->[0] =~ s/ <BR>(.*)/"<br \/>" . capitalize($1)/eg;
	    $row->[1] = capitalize($row->[1]);
	    $row->[1] =~ s/([A-Z]r?)$/$1./;
	    $row->[3] =~ s/-/-<wbr \/>/g;
	    $row->[5] =~ s/ON CAMPUS<br \/>//g;
	    $row->[5] =~ s/<br \/>/ /g;
	    print '<tr><td>';
	    print join('</td><td>', @$row);
	    print "</td></tr>\n";
	}
    }
    print "</table>\n";
}

sub do_html_grades {
    my @readheaders = ("Section ID", "Course Title", "Grade", "Earned  Hours", "Quality  Hours", "Quality  Points", "GPA");
    my @showheaders = ("Section ID", "Course Title", "Grade", "Earned<br />Hours", "Quality<br />Hours", "Quality<br />Points", "GPA");
    my ($row, $lastrow);
    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
    my $response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN|Term&tserve_trans_config=rgrdterm.cfg"); # Valid grading terms
    die $response->status_line unless $response->is_success;
    my @terms = grep {s/^<option value="([^"]*)">.*/$1/} (split( /\r\n/, $response->content));
    foreach(@ARGV || reverse @terms) {
	$response = $ua->get("$url&tserve_tip_write=||WID|SID|PIN|Term&tserve_trans_config=rgrades.cfg&Term=".($_) );
	die $response->status_line unless $response->is_success;
	$te->parse($response->content);
    }
    print '<table cellpadding="3" cellspacing="0">'."\n<tr><th>";
    print join("</th><th>",@showheaders);
    print "</th></tr>\n";
    foreach $ts ($te->table_states) {
	foreach $row ($ts->rows) {
	    map { s/\xa0//g; s/\n/<br \/>/g; $_} @$row;
	    $row->[1] = capitalize($row->[1]);
	    $lastrow=$row;
	    next if $row->[0] =~ /:/;
	    print '<tr><td>';
	    print join('</td><td>', @$row);
	    print "</td></tr>\n";
	}
    }
    print '<tr><td colspan="2">', capitalize($lastrow->[0]);
    shift @$lastrow; shift @$lastrow;
    print "</td><td>";
    print join('</td><td>', @$lastrow);
    print "</td></tr>\n";
    print "</table>\n";
}

if (defined($ARGV[0]) && $ARGV[0] eq "-g") {
    shift;
    do_html_grades;
} elsif (defined($ARGV[0]) && $ARGV[0] eq "-s") {
    shift;
    do_html_schedule;
} else {
    do_mhc_schedule;
}

$ua->get("$url&tserve_trans_config=alogout.cfg"); # Logout