#!/usr/bin/perl -w
# $Id$
# -*- perl -*- vim: ft=perl sw=4 sts=4

# Brief usage instructions:
# Create a ~/.sct6rc that has SID=yourssn and PIN=yourpin
# You'll need to change the url below if you go anywhere but TAMUK.

# Update: This tool now only outputs in XML.  For other formats, convert
# with schedproc

use strict;
use Date::Calc::Object qw(Day_of_Week Decode_Day_of_Week Decode_Month Week_of_Year Monday_of_Week Day_of_Week_Abbreviation Delta_Days Add_Delta_Days Nth_Weekday_of_Month_Year Gmtime Mktime);
use Date::Calendar::Profiles qw($Profiles);
use Date::Calendar::Year;
use HTML::TableExtract;
use LWP::UserAgent;
use XML::Simple;
use vars qw($ua %opts %faculty);

my ($response);

$opts{'holidays'} = { # %{$Profiles->{'US-TX'}},
    "Martin Luther King Day"    => "3/Mon/Jan",
    "Good Friday"               => "-2",
    "Spring Break Monday"       => \&Spring_Break,
    "Spring Break Tuesday"      => \&Spring_Break,
    "Spring Break Wednesday"    => \&Spring_Break,
    "Spring Break Thursday"     => \&Spring_Break,
    "Spring Break Friday"       => \&Spring_Break,
    "Spring Break Saturday"     => \&Spring_Break,
    "Study Day"                 => "4/Thu/Apr", # ?
    "Memorial Day"              => "5/Mon/May",
    "Independence Day"          => \&US_Independence,
    "Labor Day"                 => \&US_Labor,
    #"Columbus Day"              => "2/Mon/Oct",
    "Thanksgiving Day"          => "4/Thu/Nov",
    "Thanksgiving Friday"       => \&Thanksgiving_Friday,
};

sub Spring_Break {
    my($year,$label) = @_;
    $label =~ s/^Spring Break //;
    return( Add_Delta_Days(
            Nth_Weekday_of_Month_Year($year,1,1,1),
            7*(11-1) # This is for the 11th Monday of the year
            +Decode_Day_of_Week($label)-1) );
}

sub Thanksgiving_Friday {
    my($year,$label) = @_;
    return( Add_Delta_Days(Nth_Weekday_of_Month_Year($year,11,4,4), 1) );
}
sub US_Independence # Fourth of July
{
    my($year,$label) = @_;
    return( &Date::Calendar::Profiles::Nearest_Workday($year,7,4) );
}
sub US_Labor # First Monday after the first Sunday in September
{
    my($year,$label) = @_;
    return( Add_Delta_Days(
        Nth_Weekday_of_Month_Year($year,9,7,1), +1) );
}

my $config = $ENV{HOME} . "/.sct6rc";
if (($ARGV[0] || "") eq '-F') {
    shift;
    $config = shift;
}

my $arg = "";
$arg = shift if (defined($ARGV[0]) && $ARGV[0] =~ /^-\w$/);

if (-r $config) {
    open CONFIG, $config;
    while(<CONFIG>) {
        s/\#.*//;
        next unless m/^([^=]*)=(.*)/;
        $opts{$1}=$2;
    }
    close CONFIG;
}
my $domain = $opts{'domain'} || "as1.tamuk.edu:9003";
my $url = "https://$domain/pls/PROD/";
$url = $opts{'url'} if(defined($opts{'url'}));

$ua = LWP::UserAgent->new;
$ua->timeout(10);
$ua->env_proxy;
$ua->cookie_jar( {} );
$response = $ua->get("${url}twbkwbis.P_WWWLogin") or die "$!";
$response = $ua->post("${url}twbkwbis.P_ValLogin", { sid => $opts{SID}, PIN => $opts{PIN} }) or die "$!";

my %hiddenjunk;
{
    my $content = $response->content;
    while($content =~ /<input type="hidden" name="(.*?)" value="(.*?)">/gi) {
        $hiddenjunk{$1} = $2;
    }
}
$hiddenjunk{usage_btn} = "Continue";
$response = $ua->post("${url}twbkwbis.P_FirstMenu", \%hiddenjunk); 
die $response->status_line unless $response->is_success;

$response = $ua->get("${url}bwskflib.P_SelDefTerm"); # Valid terms
die $response->status_line unless $response->is_success;
my @terms = grep {s/^<option value="([^"]*)">.*/$1/i} (split( /\r?\n/, $response->content)); # "
die "Site down. Try again later.\n" unless (@terms);

sub next_class {
    my %class = @_;
    $class{'duration'} =~ /(\d\d\d\d)(\d\d)(\d\d)-(\d\d\d\d)(\d\d)(\d\d)/;
    my $days = Delta_Days($1,$2,$3,$4,$5,$6);
    my $firstday = Date::Calc->new($1,$2,$3);
    my $lastday = Date::Calc->new($4,$5,$6);
    my $today = Date::Calc->new(Date::Calc->localtime(time+3600*6)->date);
    my @days=();
    foreach(split(" ",$class{'days'})) {
        push @days, Decode_Day_of_Week($_);
    }
    my @off = @{$class{'off'}};
    for($today = ($today > $firstday ? $today : $firstday); $today < $lastday; $today++) {
        next unless(grep($_ == Day_of_Week($today->date), @days));
        next if(grep($_ == $today, @off));
        return $today;
    }
    $today = Date::Calc->new(Date::Calc->gmtime->date);
    for($today = ($today < $lastday ? $today : $lastday); $today > $firstday; $today--) {
        next unless(grep($_ == Day_of_Week($today->date), @days));
        next if(grep($_ == $today, @off));
        return $today;
    }
    return undef;
}

sub off_for_holidays {
    my %class = @_;
    my %days = (M => "Mon", T => "Tue", W => "Wed", R => "Thu", F => "Fri", S => "Sat", U => "SU");
    my $d = $class{'days'};
    $d =~ s/([MTWRFS])/ $days{$1}/g;
    $d =~ s/^ //;
    $class{'duration'} =~ /(\d\d\d\d)(\d\d)(\d\d)-(\d\d\d\d)(\d\d)(\d\d)/;
    my $days = Delta_Days($1,$2,$3,$4,$5,$6);
    my $firstday = Date::Calc->new($1,$2,$3);
    my $lastday = Date::Calc->new($4,$5,$6);
    my $year = Date::Calendar::Year->new($1, $opts{'holidays'});
    my @holidays=();
    my @days=();
    foreach(split(" ",$d)) {
        $days[Decode_Day_of_Week($_)] = 1;
    }
    foreach ($year->search("")) {
        my $good=1;
        #foreach my $x ($year->labels($_)) {
        #    $good=0 if ($x =~ /Veteran/ or $x =~ /President/);
        #}
        next unless ($year->is_full($_) && $_>=$firstday && $_<=$lastday);
        push @holidays, $_
            if (defined($days[Day_of_Week($_->date)]) && $good > 0);
    }
    return wantarray ? @holidays : "@holidays";
}

sub off_for_exams {
    my %class = @_;
    my $time = $class{'begin'} . "-" . $class{'end'};
    $class{'duration'} =~ /\d{8}-(\d\d\d\d)(\d\d)(\d\d)/;
    my $lastday = Date::Calc->new($1,$2,$3);
    return wantarray ? () : undef unless (Day_of_Week($lastday->date) == 7);
    my $beginning="(08:00-09:15|11:00-12:15|14:00-15:15|17:00-18:15|17:30-18:45|20:00-21:15|20:30-21:45)";
    my $ending   ="(06:30-07:45|09:30-10:45|12:30-13:45|15:30-16:45|18:30-19:45|19:00-20:15)";
    my $days = join(" ",map {Decode_Day_of_Week($_)} split(/ /, $class{'days'}));
    if($days eq "1 3") {
        if($time =~ /$beginning/) {
            return $lastday-4;
        } elsif($time =~ /$ending/) {
            return $lastday-6;
        }
    } elsif($days eq "2 4") {
        if($time =~ /$beginning/) {
            return $lastday-3;
        } elsif($time =~ /$ending/) {
            return $lastday-5;
        }
    } elsif($days eq "5") {
        return $lastday-2;
    }
    return wantarray ? () : "";
}

sub capitalize {
    local $_ = shift || "";
    s/ +$//;
    s/\b([A-Z])([A-Z]*)\b/$1\L$2/g;
    s/\b(I)(i*)\b/$1\U$2/g;
    s/\bUs\b/US/g;
    s/ (And|For|Of|Or|The|To|With) / \l$1 /g;
    s/\b(Mc)([a-z])/$1\u$2/g;
    s/\b(Tcp\/Ip|Pc|Tba)\b/\U$&/g;
    s/\bThru\b/Through/g;
    s/\bAcct\b/Accounting/g;
    s/\bAmer\b/American/g;
    s/\bChem\b/Chemistry/g;
    s/\bComp\b/Composition/g;
    s/\bFed\b/Federal/g;
    s/\bGen\b/General/g;
    s/\bIntro\b/Introduction/g;
    s/\bPrgm\b/Programming/g;
    s/\bOp Sys\b/Operating System/g;
    #s/\bGovt\b/Government/g;
    s/\bLit\b/Literature/g;
    s/\bPrin\b/Principles/g;
    s/\bBus\b/Business/g;
    s/\bSyst\b/Sys/g;
    return $_;
}

sub get_schedule_terms {
    my (@sterms, @a);
    @a=('10','20','30','40');   # Fall, Spring, Summer I, Summer II
                                # Last 3 are currently guesses
    my @localtime=localtime();
    if ($localtime[4]<3) { # Through Mar 31
        @sterms=((1900+$localtime[5]).$a[1]);
    } elsif ($localtime[4]<5) { # Through May 31
        @sterms=((1900+$localtime[5]).$a[1],(1900+$localtime[5]).$a[2]);
    } elsif ($localtime[4]<7) { # through July 31
        @sterms=((1900+$localtime[5]).$a[2],(1900+$localtime[5]).$a[3]);
    } elsif ($localtime[4]<8) { # through Aug 31
        @sterms=((1900+$localtime[5]).$a[3],(1901+$localtime[5]).$a[0]);
    } elsif ($localtime[4]<10) { # through Oct 31
        @sterms=((1901+$localtime[5]).$a[0]);
    } else {
        @sterms=((1901+$localtime[5]).$a[0],(1901+$localtime[5]).$a[1]);
    }
    return @sterms;
}

sub get_schedule {
    my @readheaders = ("Type", "Time", "Days", "Where", "Date Range", "Schedule Type", "Instructors");
    my @class;
    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
    my (@schedule, @terms, $classid, $title, $begin, $end, $times, $days, $session);
    @terms = get_schedule_terms();
    foreach (@_ ? @_ : @terms) {
        $response = $ua->get("${url}bwskfshd.P_CrseSchdDetl?term_in=$_" );
        die $response->status_line unless $response->is_success;
        $te->parse($response->content);
        foreach my $l (split (/\n/, $response->content)) {
            next unless $l =~ s/.*<CAPTION class=[^>]*>(.* - .... \d\d\d\d \d\d\d)<\/caption>.*/$1/i;
            push @class, $l;
        }
    }
    foreach my $ts ($te->table_states) {
        foreach my $row ($ts->rows) {
            #map { s/\xa0//g; $_} @$row;
            #$row->[0] =~ s/.*launchWebCT\("([^"]*)"\).*/$1/s;
            #$row->[0] =~ s/(.*) ?<[Bb][Rr][^>]*>(.*)/capitalize($2)/eg;
            $classid = (shift @class);
            $title = $classid;
            $classid =~ s/.* - //;
            $classid =~ s/ /-/g;
            $title =~ s/ - .*//;
            $row->[6] =~ s/\b([A-Z]r?)$/$1./;
            $row->[6] = capitalize($row->[6]);
            $row->[6] =~ s/ *\([A-Z]\)//;
            $row->[1] =~ s/ ?([ap])m/\u$1M/g;
            $row->[1] =~ s/ - /-/;
            ($begin, $end) = split(/ ?- ?/, $row->[1]);
            $begin =~ s/^(\d):/0$1:/;
            $end =~ s/^(\d):/0$1:/;
            if (($begin=~/PM$/ && $begin!~/^12/)||($begin=~/^12:..AM/)) {
                $begin =~ s/^(\d?\d)/($1+12)%24/e;
            }
            if (($end=~/PM$/ && $end!~/^12/)||($end=~/^12:..AM/)) {
                $end =~ s/^(\d?\d)/($1+12)%24/e;
            }
            $begin =~ s/ ?[AP]M//;
            $end =~ s/ ?[AP]M//;
            $row->[4] =~ s/([A-Za-z]{3,9})/(Decode_Month($1)<10?"0":"").Decode_Month($1)/eg;
            $row->[4] =~ s/(\d\d?) (\d\d), (\d\d\d\d)/$3$1$2/g;
            $row->[4] =~ s/ - /-/;
            $row->[3] =~ s/(ON|MAIN) CAMPUS\n|Palo Alto Building \d* //ig;
            $row->[3] =~ s/\n/ /g;
            my %class = (
                id => $classid,
                title => capitalize($title),
                instructor => $row->[6],
                days => $row->[2],
                #'time' => $row->[1],
                begin => $begin,
                end => $end || undef,
                duration => $row->[4],
                location => $row->[3],
            );
            my @off = ( map { "$_"; } (off_for_holidays(%class), off_for_exams(%class)));
            $class{'off'} = [ @off ] if (@off);
            push @schedule, \%class;
        }
    }
    return @schedule;
}

sub do_xml_schedule {
    my $file = shift if (defined $_[0] and $_[0] !~ /^\d/);
    my $schedule = { class => [ get_schedule(@_) ] };
    my $xml = XMLout($schedule, NoAttr => 1, RootName => 'schedule');
    if($file) {
        open FH, ">$file";
        print FH $xml;
        close FH;
    } else {
        print $xml;
    }
}

#sub do_xml_grades {
#    print "<grades>\n</grades>\n";
#}

sub do_xml_grades {
    #my @readheaders = ("Subject", "Course", "Section", "Course Title", "Final Grade", "Attempted", "Earned", "GPA Hours", "Quality Points");
    my @readheaders = ("Subject", "Course", "Section", "CTitle", "Final Grade", "Attempted", "Earned", "GPA Hours", "Quality Points");
    my ($row, $lastrow);
    my $te = new HTML::TableExtract( headers => [ @readheaders ] );
    my $response = $ua->get("$url/bwskogrd.P_ViewTermGrde"); # Valid grading terms
    die $response->status_line unless $response->is_success;
    #my @terms = reverse grep {s/^<option value="([^"]*)">.*/$1/} (split( /\r\n/, $response->content));
    my @grades = ();
    my @terms = ();
    my $year = Date::Calc->localtime->year;
    for(my $y=$year-3;$y<=$year+1;$y++) { push @terms, ($y.10,$y.20,$y.30,$y.40); }
    foreach(@_ ? @_ : @terms) {
        $response = $ua->get("$url/bwskogrd.P_ViewGrde?term_in=".($_) );
        die $response->status_line unless $response->is_success;
        my $content = $response->content;
        $content =~ s/Course Title/CTitle/g;
        $te->parse($content);
    }
    foreach my $ts ($te->table_states) {
        foreach my $row ($ts->rows) {
            map { s/^\s+//; s/\xa0|\r//g; s/\n/<br \/>/g; $_} @$row;
            $row->[3] = capitalize($row->[3]);
            $row->[3] =~ s/&/&amp;/g;
            #$row->[0] =~ s/Cumulative through/Cumulative: through/;
            #$row->[0] =~ s/Cumulative:(.*) (\d{4}) (.*)/Cumulative:$1 $3 $2/;
            $lastrow=$row;
            next if $row->[0] =~ /:|Current Term/;
            push @grades, {
                id => $row->[0]."-".$row->[1]."-".$row->[2],
                title => $row->[3],
                grade => $row->[4],
                attempted => $row->[5],
                earned => $row->[6],
                hours => $row->[7],
                points => $row->[8]
            };
        }
    }
    $lastrow->[0] =~ s/Cumulative:? *through *//i if($lastrow->[0]);
    my $cumulative = { term => capitalize($lastrow->[0]),
                       gpa => $lastrow->[6],
                       earned => $lastrow->[3],
                       hours => $lastrow->[4],
                       points => $lastrow->[5]
                   };
    my $xml = XMLout({class => [@grades], cumulative => []}, NoAttr => 1, RootName => 'grades');
    print $xml;
    return;
}

sub do_transcripts {
    print "Not implemented.\n";
}

if ($arg eq "-g") {
    do_xml_grades(@ARGV);
} elsif ($arg eq "-t") {
    do_transcripts;
} elsif ($arg eq "-x" || $arg eq "-s" || 1) {
    do_xml_schedule(@ARGV);
}

$ua->get("${url}twbkwbis.P_Logout"); # Logout